虚数乗法の具体例をもっと計算してみよう（類数1の場合）

今週は、虚数乗法をテーマとする記事を２本公開しました！
tsujimotter.hatenablog.com
tsujimotter.hatenablog.com

おかげさまでたくさんの方々に見ていただき、たくさん反響もありました。
虚数乗法は、tsujimotterがこれまで時間をかけて勉強してきたテーマの一つなので、その魅力を伝えることができて大変うれしく思います。

シリーズ前編・後編の記事を通して、

$E\colon y^2 = x^3 + x$

というただ１つの楕円曲線の例を扱ってきましたが、書き終わってみてもっとたくさんの具体例で計算してみたいと思うようになりました。欲張りですね。笑

そんなわけで、今回はたくさんの具体例を計算してみようという記事にしようと思います。

ところで、前回の記事では言及し忘れていたのですが、そもそも虚数乗法を持つ楕円曲線はレアなのです。適当にやっても簡単には見つからないわけですね。

そこで、探し方も含めて紹介し、ほかの楕円曲線を計算し、それぞれのray類体を計算するところをやってみたいと思います。

なお、今回は虚2次体の類数が1の場合に限定して紹介したいと思います。2以上の類数のケースについては、また今度にしたいと思います。

目次：

虚2次体の類数が1の場合のリスト

① ℚ(√-3) の場合

E[2] の計算

E[3] の計算

E[4] の計算

② ℚ(√-7) の場合

③ ℚ(√-163) の場合

おわりに

続き

虚2次体の類数が1の場合のリスト

実は、虚2次体 $K$ の類数が1の場合については、 $\mathcal{O}_K$ に虚数乗法を持つ楕円曲線のリストがまとめられているのを見つけました。

examples of elliptic curves with complex multiplication

虚2次体 $K$ に対応して、 $\mathcal{O}_K$ に虚数乗法を持つ楕円曲線が1種類ずつ掲載されています。

類数が1の場合、実は本質的に1種類しか楕円曲線が存在しないことがわかります。同型な楕円曲線同士をひとまとめにすると、実質的に1種類になるという意味ですが、実はこの個数は $K$ の類数が 1 であることに関係しています！！

大変面白い話なので、またいずれ説明したいと思います。

一覧をこちらにも掲載しておきましょう：

虚2次体 $K$	$\mathcal{O}_K$ に虚数乗法を持つ楕円曲線
$\mathbb{Q}(\sqrt{-1})$	$y^2 = x^3 + x$
$\mathbb{Q}(\sqrt{-2})$	$y^2 = x^3 + 4x^2 + 2x$
$\mathbb{Q}(\sqrt{-3})$	$y^2 + y = x^3$
$\mathbb{Q}(\sqrt{-7})$	$y^2 + xy = x^3 - x^2 - 2x - 1$
$\mathbb{Q}(\sqrt{-11})$	$y^2 + y = x^3 - x^2 - 7x + 10$
$\mathbb{Q}(\sqrt{-19})$	$y^2 + y = x^3 - 38x + 90$
$\mathbb{Q}(\sqrt{-43})$	$y^2 + y = x^3 - 860x + 9707$
$\mathbb{Q}(\sqrt{-67})$	$y^2 + y = x^3 - 7370x + 243528$
$\mathbb{Q}(\sqrt{-163})$	$y^2 + y = x^3 - 2174420x + 1234136692$

類数1の虚2次体が上記の9個しか存在しないことについては、以前紹介しましたね！
tsujimotter.hatenablog.com

今回は $\mathbb{Q}(\sqrt{-3}), \;\; \mathbb{Q}(\sqrt{-7}), \;\; \mathbb{Q}(\sqrt{-163})$ のケースについて、実際にSagemathを使って計算してみましょう。

① ℚ(√-3) の場合

まずは対応する楕円曲線 $E\colon y^2 + y = x^3$ を定義して、グラフを表示してみましょう：

E = EllipticCurve([0,0,0,1,0]); E
E.plot()

f:id:tsujimotter:20200706224017p:plain:w400

E[2] の計算

それではいつものように $E$ の2等分点 $E[2]$ から計算してみましょう。等分多項式は

div_poly = E.division_polynomial(2); div_poly
f = div_poly.factor(); f

4*x^3 + 1
(4) * (x^3 + 1/4)

等分多項式の因数分解が

$4x^3 + 1 = 4(x^3 + 1/4)$

とかけるということですね。ということは、 $E[2]$ の $x$ 座標のリストは

$\displaystyle x = -\frac{1}{\sqrt[3]{4}}, \;\; -\frac{1}{\sqrt[3]{4}}\omega, \;\; -\frac{1}{\sqrt[3]{4}}\omega^2$

とかけるということです。ここで $\omega = \frac{1+\sqrt{-3}}{2}$ としています。

3つの $x$ 座標に対して、1個ずつの $y$ 座標が対応し、加えて無限遠点 $O$ を入れて4点になります。実際、各 $x$ 座標を代入して

$\begin{align} y^2 + y = -\frac{1}{4} \end{align}$

を解くと、解は $y = -1/2$ となります。

よって、計算結果はこうなります：

$\begin{align} E[2] = \bigg\{ O, \; \left(-\frac{1}{\sqrt[3]{4}}, \; -\frac{1}{2}\right), \; \left(-\frac{1}{\sqrt[3]{4}}\omega, \; -\frac{1}{2}\right), \; \left(-\frac{1}{\sqrt[3]{4}}\omega^2, \; -\frac{1}{2}\right) \bigg\} \end{align}$

さて、あとはこの $x$ 座標を添加した体を考えたいところですが・・・。ちょっと待ってください。ウェーバー関数の定義を再確認しましょう：

（前回の記事から再掲）
ウェーバー関数 $h$ についてはまだ説明していませんでしたので、ここで説明しておきたいと思います。次のように定義されます。
まず、 $K$ に虚数乗法を持つ楕円曲線 $E$ として、係数体がそのヒルベルト類体 $H = K(j(E))$ にあるモデルを取る必要があります。このようなモデルがとれることは、前節で述べました。その上で、 $E$ の定義方程式が
$E\colon y^2 = x^3 + Ax + B$
と表されるとします。もちろん $A, B \in H$ です。
このとき、点 $P = (x, y) \in E$ に対して $h(P)$ を次のように定義します。
$\displaystyle h(P) = \begin{cases} x & (AB \neq 0) \\ x^2 & (B = 0) \\ x^3 & (A = 0) \end{cases}$

よくよく考えてみると、今回の定義方程式は

$E\colon y^2 + y = x^3$

となっており、ウェーバー関数の適用できるモデルと異なりますね。というわけで、同型な別のモデルをとり直す必要があるわけです。

こういう問題は実際に具体例で確認してみないと、なかなか気づきませんよね。勉強になります。

さて、結論からいうと、我々の楕円曲線 $E\colon y^2 + y = x^3$ に対して、変数変換

$x = X, \;\; y = Y + \frac{1}{2}$

をすればよいです。 $y$ について「平方完成」するイメージですね。変換ルールを適用すると

$(Y - \frac{1}{2})^2 + (Y - \frac{1}{2}) = X^3$

$\therefore Y^2 - Y + \frac{1}{4} + Y - \frac{1}{2} = X^3$

$\therefore Y^2 = X^3 + \frac{1}{4}$

ここで、 $E' \colon Y^2 = X^3 + \frac{1}{4}$ とおくと、この変数変換により同型写像

$\begin{align} \phi\colon E &\longrightarrow E' \\ (x, y) & \longmapsto (x, y-\frac{1}{2}) \end{align}$

が得られました。

楕円曲線 $E'$ の定義方程式はウェーバー関数における前提条件を満たすので、そのまま使えます。さらにいうと、 $E$ と $E'$ の $x$ 座標は変わらないので、 $E[2]$ の $x$ 座標をそのまま使ってよいことになりますね。

ここで、 $P = (x, y) \in E$ に対して $h(P) = x^3$ であることに注意すると

$\begin{align} h(E[2]) = \bigg\{ \left(-\frac{1}{\sqrt[3]{4}}\right)^3, \; \left(-\frac{1}{\sqrt[3]{4}}\omega\right)^3, \; \left(-\frac{1}{\sqrt[3]{4}}\omega^2\right)^3 \bigg\} \end{align}$

となりますが、 $\omega^3 = 1$ であるので

$\begin{align} h(E[2]) = \bigg\{ -\frac{1}{4} \bigg\} \end{align}$

ということですね。

ここまできて非常に残念なことに気づいたのですが、 $\mathbb{Q}(\sqrt{-3})$ に $h(E[2])$ を添加しても非自明な拡大は引き起こさないです。。。

というわけで、 $E[2]$ は計算しても、今回の目的では意味がないことが分かりました。。。

E[3] の計算

気を取り直して3等分点 $E[3]$ を計算してみましょう。等分多項式は

div_poly = E.division_polynomial(3); div_poly
f = div_poly.factor(); f

3*x^4 + 3*x
(3) * x * (x + 1) * (x^2 - x + 1)

等分多項式の因数分解が

$3x^4 + 3x = 3x(x+1)(x^2 - x + 1)$

とかけるということですね。ということは、 $E[3]$ の $x$ 座標のリストは

$\displaystyle x = 0, \; -1, \; -\omega, \; -\omega^2$

ということになります。4つの $x$ 座標につき、2個ずつの $y$ 座標が対応し、加えて無限遠点 $O$ を入れて9点になります。ちゃんと $\# E[3] = 3^2$ が成り立っていそうですね。

各 $x$ 座標を代入して

$\begin{align} y^2 + y &= 0 \\ y^2 + y &= (-1)^3 \\ y^2 + y &= \left(-\omega\right)^3 \\ y^2 + y &= \left(-\omega^2 \right)^3 \end{align}$

を解けばいいですね。

実際、計算結果はこうなります：

$\begin{align} E[3] = \bigg\{ O, \; (0, 0), \; (0, -1), \; (-1, \omega), \; (-1, \omega^2), \\ (-\omega, \omega), \; (-\omega, \omega^2), \;(-\omega^2, \omega), \; (-\omega^2, \omega^2) \bigg\} \end{align}$

しかしながら、このケースでも $x$ 座標を3乗したものは拡大を引き起こしません・・・。なかなか難しいですね。

E[4] の計算

最後に、 $E[4]$ を計算しましょう。まずは等分多項式を計算します。

div_poly = E.division_polynomial(4); div_poly
f = div_poly.factor(); f

結果は次の通りです：

8*x^9 + 42*x^6 + 6*x^3 - 1
(8) * (x^3 + 1/4) * (x^6 + 5*x^3 - 1/2)

全体としては8次の多項式になり、「3次の既約多項式（ $E[2]$ のときに計算したもの）」と新しく登場した「6次の既約多項式」の積に分解されますね。

後者の方を $g(x) = x^6 + 5*x^3 - 1/2$ と置き、6つの根を求めてみましょう。

g = f[1][0]; g   # 多項式 g(x) = x^6 + 5*x^3 - 1/2 だけを取り出す
solve(g(x), x)

結果はこちらです：

x^6 + 5*x^3 - 1/2
[x == 1/2*I*sqrt(3)*(3/2*sqrt(3) - 5/2)^(1/3) - 1/2*(3/2*sqrt(3) - 5/2)^(1/3), x == -1/2*I*sqrt(3)*(3/2*sqrt(3) - 5/2)^(1/3) - 1/2*(3/2*sqrt(3) - 5/2)^(1/3), x == (3/2*sqrt(3) - 5/2)^(1/3), x == 1/2*I*sqrt(3)*(-3/2*sqrt(3) - 5/2)^(1/3) - 1/2*(-3/2*sqrt(3) - 5/2)^(1/3), x == -1/2*I*sqrt(3)*(-3/2*sqrt(3) - 5/2)^(1/3) - 1/2*(-3/2*sqrt(3) - 5/2)^(1/3), x == (-3/2*sqrt(3) - 5/2)^(1/3)]

なるほど、ちょっと書き写すのが大変そうですね。

latex(solve(g(x), x))

とすると、結果がLaTeX化されるので、多少見やすくなります。少し手直ししてLaTeX化したものを画像にすると次のようになります：

f:id:tsujimotter:20200707214417p:plain:w300

うーん、ちょっとこれはしんどそうですね。。。

しかし、実は

$\displaystyle \alpha = \left(\frac{3}{2}\sqrt{3} - \frac{5}{2}\right), \;\; \beta = \left(-\frac{3}{2}\sqrt{3} - \frac{5}{2}\right)$

と置くだけで、次のように綺麗に整理できます：

$\begin{align} x_1 &= \left(\frac{-1+\sqrt{-3}}{2}\right) \sqrt[3]{\alpha} \\ x_2 &= \left(\frac{-1-\sqrt{-3}}{2}\right) \sqrt[3]{\alpha} \\ x_3 &= \sqrt[3]{\alpha} \\ x_4 &= \left(\frac{-1+\sqrt{-3}}{2}\right) \sqrt[3]{\beta} \\ x_5 &= \left(\frac{-1-\sqrt{-3}}{2}\right) \sqrt[3]{\beta} \\ x_6 &= \sqrt[3]{\beta} \end{align}$

こんな風に計算できることは、@icqk3 さん、@jun2nosimobe さんに教えていただきました。ありがとうございます。

係数は単に1の3乗根なので、ウェーバー関数を通すと（3乗すると）

$h(E[4]) = \{ \alpha, \; \beta \}$

となります。

よって、 $K = \mathbb{Q}(\sqrt{-3})$ 上の導手 $(4)$ のray類体 $K_{(4)}$ は

$K_{(4)} = K(\sqrt{3}) = \mathbb{Q}(\sqrt{-3}, \sqrt{3})$

であることが計算できました！！！　おめでとうございます！！！

「4等分点なのに $\sqrt{3}$ が出てくるというのは、円のときと状況が違うな」と一瞬思ったのですが、 $\sqrt{3} = -\sqrt{-1}\sqrt{-3}$ なので

$K_{(4)} = K(\sqrt{3}) = \mathbb{Q}(\sqrt{-3}, \sqrt{-1})$

としても良いわけです。そう考えると、 $\sqrt{-1}$ は1の原始4乗根なので、たしかに4等分っぽさが出てきますね。

ray類体が求まったので、素イデアルの分解法則を見てみましょう。

導手が $(4) = 4\mathbb{Z}[\omega]$ なので、 $(4)$ と素な $K = \mathbb{Q}(\sqrt{-3})$ の素イデアル $\mathfrak{p} = (\pi)$ の中で、特に

$\pi \equiv 1 \pmod{4\mathbb{Z}[\omega]}$

を満たすものが $K_{(4)}$ において完全分解します。 $\mathbb{Q}(\sqrt{-3})$ の類数は1なので、すべてのイデアルが単項イデアルと仮定してよく、議論を楽にしてくれますね。

注意しなければならないのが、整数環 $\mathbb{Z}[\omega]$ における単数の取り扱いです。 $\mathbb{Z}[\omega]$ の単数は

$1, \; -1, \; \omega, \; -\omega, \; \omega^2, \; -\omega^2$

の6つあり、それぞれ $\pi$ にかけた

$\pi, \; -\pi, \; \omega\pi, \; -\omega\pi, \; \omega^2\pi, \; -\omega^2\pi$

がすべて同じイデアルを生成します。

したがって、完全分解する条件としては

$\pi \equiv 1 \pmod{4\mathbb{Z}[\omega]}$

$\pi \equiv -1 \pmod{4\mathbb{Z}[\omega]}$

$\pi \equiv \omega \pmod{4\mathbb{Z}[\omega]}$

$\pi \equiv -\omega \pmod{4\mathbb{Z}[\omega]}$

$\pi \equiv \omega^2 \pmod{4\mathbb{Z}[\omega]}$

$\pi \equiv -\omega^2 \pmod{4\mathbb{Z}[\omega]}$

を満たすもの全てを考える必要があることに注意しましょう。

ここで、 $\mathbb{Z}[\omega]$ を図示するとこうなりますね。

f:id:tsujimotter:20200709110616p:plain:w400

図の色のついた点が素元であれば、その素元 $\pi$ に対して $(\pi)$ が $K_{(4)}$ で完全分解することになります。

$\pi$ として実軸上のものだけに限定して考えるのであれば、単純に $\pi, \; -\pi$ だけを考えれば十分ですね。

以下では、 $\pi$ として $\mathbb{Z}[\omega]$ における素元であって

$\pi \equiv 1 \pmod{4\mathbb{Z}[\omega]}$
または
$\pi \equiv -1 \pmod{4\mathbb{Z}[\omega]}$

を満たすものを特別に考えることにしましょう。つまり、 $\mathbb{Z}[\omega]$ の素元であって、（ $2$ を除く）素数に一致するものすべて、ということになりますね！

「 $\mathbb{Z}[\omega]$ における素元」が「 $\mathbb{Z}$ の素数でもある」ということは、つまり $\mathbb{Z}[\omega]$ において惰性する素数でなければなりません。そして、 $\mathbb{Z}[\omega]$ において惰性する素数は、 $3$ で割って $2$ あまる素数でした。

というわけで、 $\pi = 17$ としてみましょう。 $(17)$ が $K_{(4)}$ で完全分解することを確認します。

まずは、Sagemathで $K_{(4)}$ を定義します。

K.<a> = NumberField(x^2 + 3); K
L.<b> = K.extension(x^2 - 3); L

この $L$ が $K_{(4)}$ ですね。結果は次の通り：

Number Field in a with defining polynomial x^2 + 3
Number Field in b with defining polynomial x^2 - 3 over its base field

ここで、 $(17)$ の素イデアル分解を計算しましょう

K.factor(17)
L.factor(17)

結果は以下の通り：

Fractional ideal (17)
(Fractional ideal ((-1/6*a - 1/2)*b - 2*a + 2)) * (Fractional ideal ((1/6*a - 1/2)*b + 2*a + 2))

$(17)$ が $K$ の素イデアルであり、 $K_{(4)}$ においては以下のように分解されることが確認できました：

$\displaystyle(17)\mathcal{O}_{K_{(4)}} = \left( 2 - 2\sqrt{-3} - \left(\frac{1}{2} + \frac{1}{6}\sqrt{-3}\right)\sqrt{3}\right) \left( 2 + 2\sqrt{-3} - \left(\frac{1}{2} - \frac{1}{6}\sqrt{-3}\right)\sqrt{3}\right)$

2つの素イデアルの積に分解されていますが、 $K_{(4)}/K$ は2次拡大ですので、確かに完全分解していることがわかりますね。

$p \equiv 2 \pmod{3}$ であるような素数 $p < 300$ について、 $K_{(4)}$ で完全分解するかどうかを確認しましょう。

K.<a> = NumberField(x^2 + 3); K
L.<b> = K.extension(x^2 - 3); L

P = Primes()
p = P.first()
while p < 300:
    if p % 3 == 2:
        pk = K.factor(p)
        pl = L.factor(p)
        print p, len(pk), len(pl)
    p = P.next(p)

以下が結果です。1列目が素数 $p$ 、2列目が $K$ での分解の個数、3列目が $K_{(4)}$ での分解の個数を表します。

たしかに、 $p > 2$ かつ $p\equiv 2 \pmod{3}$ であるすべての素数 $p$ が $K_{(4)}$ で2つの素イデアルの積に分解、すなわち完全分解していることがわかりますね！

「あれ？2は一体なぜ？」と思ったかもしれません。

素イデアル分解してみると

$\displaystyle (2)\mathcal{O}_{K_{(4)}} = \left( 1 + \frac{1}{3}\sqrt{-3}\sqrt{3} \right)^2$

となるわけですが、 $(2)$ は $K_{(4)}$ で分岐するということですね。

確かに、導手 $(4)$ の類体を考えていますので、 $(2)$ が分岐するのは問題ないですね。

というわけで、 $\mathbb{Q}(\sqrt{-3})$ についてはこの辺にしておきましょう。勉強になる事項がたくさん詰まった具体例でしたね。

② ℚ(√-7) の場合

続いては $K = \mathbb{Q}(\sqrt{-7})$ に虚数乗法を持つケースを考えましょう。

$E\colon y^2 + xy = x^3 - x^2 - 2x - 1$

今度はあらかじめウェーバー関数が適用できる

$y^2 = x^3 + A x + B$

という形の定義方程式に書き換えておきましょう。

まず $E$ の定義方程式の左辺に $y^2 + xy$ が見えますが、これも平方完成によって $xy$ を消すことができます。両辺に $\frac{1}{4}x^2$ を加えて

$\displaystyle y^2 + xy + \frac{1}{4}x^2 = x^3 - x^2 - 2x - 1 + \frac{1}{4}x^2$

$\displaystyle \therefore \left(y + \frac{1}{2}x\right)^2 = x^3 - \frac{3}{4}x^2 - 2x - 1$

ここで $\xi = x, \;\; \upsilon = y + \frac{1}{2}x$ とおくと

$\displaystyle \therefore \upsilon^2 = \xi^3 - \frac{3}{4}\xi^2 - 2\xi - 1$

が得られます。

次に $\xi^2$ の項を消すために、3次方程式のチルンハウス変換 $X = \xi - \frac{1}{4}, \;\; Y = \upsilon$ を用います。

$\displaystyle \therefore Y^2 = \left(X + \frac{1}{4}\right)^3 - \frac{3}{4}\left(X + \frac{1}{4}\right)^2 - 2\left(X + \frac{1}{4}\right) - 1$

いやー、いろんなテクニックが出てきますね。

最終的に、右辺を整理すると

$\displaystyle E'\colon Y^2 = X^3 - \frac{35}{16}X - \frac{49}{32}$

となります。

さて、これで同型な楕円曲線 $E, E'$ が得られたわけですが、本当に合っているでしょうか？
前回説明したように、楕円曲線が同型であることはj不変量が等しいことと同値です。よって、j不変量を計算してみましょう。

E1 = EllipticCurve([1,-1,0,-2,-1]); E1
E1.j_invariant()

E2 = EllipticCurve([0,0,0,-35/16,-49/32]); E2
E2.j_invariant()

結果は次の通りです：

Elliptic Curve defined by y^2 + x*y = x^3 - x^2 - 2*x - 1 over Rational Field
-3375
Elliptic Curve defined by y^2 = x^3 - 35/16*x - 49/32 over Rational Field
-3375

たしかに同型になっていますね！！！　やったー！！！

さて、これで準備が完了しましたので、早速 $E'$ の等分点を計算しましょう。 $E'[2], \; E'[3]$ を計算することにします。

E = EllipticCurve([0, 0, 0, - 35/16, - 49/32]); E

print ""

f = E.division_polynomial(2); f
f.factor()
solve(f(x), x)

print ""

g = E.division_polynomial(3); g
g.factor()
solve(g(x), x)

結果は次の通りです：

Elliptic Curve defined by y^2 = x^3 - 35/16*x - 49/32 over Rational Field

4*x^3 - 35/4*x - 49/8
(4) * (x - 7/4) * (x^2 + 7/4*x + 7/8)
[x == -1/8*I*sqrt(7) - 7/8, x == 1/8*I*sqrt(7) - 7/8, x == (7/4)]

3*x^4 - 105/8*x^2 - 147/8*x - 1225/256
(3) * (x^4 - 35/8*x^2 - 49/8*x - 1225/768)
[x == -1/4*sqrt(21) - 1/2*sqrt(-7/6*sqrt(21) + 7/2), x == -1/4*sqrt(21) + 1/2*sqrt(-7/6*sqrt(21) + 7/2), x == 1/4*sqrt(21) - 1/2*sqrt(7/6*sqrt(21) + 7/2), x == 1/4*sqrt(21) + 1/2*sqrt(7/6*sqrt(21) + 7/2)]

すなわち、2次の等分多項式が

$\displaystyle 4x^3 - \frac{35}{4}x - \frac{49}{8} = 4\left(x - \frac{7}{4}\right) \left(x^2 + \frac{7}{4}x + \frac{7}{8}\right)$

と表せて、その解が

$\displaystyle x = \frac{7}{4}, \;\; -\frac{7}{8} - \frac{1}{8}\sqrt{-7}, \;\; -\frac{7}{8} + \frac{1}{8}\sqrt{-7}$

であることがわかりました。

しかし、これは残念ながら $\mathbb{Q}(\sqrt{-7})$ に入っていますので、本質的な拡大を引き起こしませんね。というわけで、 $E[2]$ はパスです。

一方、3次の等分多項式は

$\displaystyle 3x^4 - \frac{105}{8}x^2 - \frac{147}{8}x - \frac{1225}{256} = 3\left(x^4 - \frac{35}{8}x^2 - \frac{49}{8}x - \frac{1225}{768}\right)$

と表せて、その解が

$\displaystyle \begin{align} x = &-\frac{1}{4} \, \sqrt{21} - \frac{1}{2} \, \sqrt{-\frac{7}{6} \, \sqrt{21} + \frac{7}{2}}, \\ & -\frac{1}{4} \, \sqrt{21} + \frac{1}{2} \, \sqrt{-\frac{7}{6} \, \sqrt{21} + \frac{7}{2}}, \\ & \frac{1}{4} \, \sqrt{21} - \frac{1}{2} \, \sqrt{\frac{7}{6} \, \sqrt{21} + \frac{7}{2}}, \\ & \frac{1}{4} \, \sqrt{21} + \frac{1}{2} \, \sqrt{\frac{7}{6} \, \sqrt{21} + \frac{7}{2}} \end{align}$

であることがわかりました。

なかなか、いかつい形をしていますね。笑

今回のウェーバー関数は $P = (x, y) \in E'$ に対して $h(P) = x$ なので、 $K = \mathbb{Q}(\sqrt{-7})$ にそのまま $x$ の値を添加した体が、 $K$ の導手 $(3)$ のray類体になります。

g = E.division_polynomial(3); g
h = g.factor()[0][0]; h

K.<a> = NumberField(x^2 + 7); K
M.<b> = K.extension(h); M
L.<c> = M.galois_closure(); L

先ほどの等分多項式の根から最小多項式を求めるのは大変なので、少し工夫しています。まず、等分多項式

$\displaystyle g(x) = 3x^4 - \frac{105}{8}x^2 - \frac{147}{8}x - \frac{1225}{256}$

の根の一つを $K$ に添加した拡大 $M/K$ を作ります。

このとき、 $M/K$ はガロア拡大ではないので、ガロア閉包をとって $L$ としています。これで

$L = K_{(3)} = K( h(E'[3]) )$

が得られたことになります。

それでは、 $K = \mathbb{Q}(\sqrt{-7})$ の素イデアルを $K_{(3)}$ に持ち上げたときの素イデアル分解について考えてみましょう。

$\mathbb{Z}[\frac{1+\sqrt{-7}}{2}]$ の単数 $\pm 1$ を考慮すると、素元 $\pi$ であって

$\pi \equiv \pm 1 \bmod{3\mathbb{Z}[\frac{1+\sqrt{-7}}{2}]}$

を満たす素元 $\pi$ によって生成される素イデアル $(\pi)$ が、 $K_{(3)}$ で完全分解する素イデアルとなります。

例によって $\mathbb{Z}[\frac{1+\sqrt{-7}}{2}]$ を図示すると、以下の赤色と青色の点が $K$ の素元であれば完全分解することになります。

f:id:tsujimotter:20200709200135p:plain:w400

$\mathbb{Q}(\sqrt{-3})$ のときと同様、 $3$ ではない素数 $p$ であって $K = \mathbb{Q}(\sqrt{-7})$ で惰性する素数（ $p \equiv 3, 5, 6 \pmod{7}$ ）は、すべて $K_{(3)}$ で完全分解することになります。

例として、 $\pi = 17$ を素イデアル分解してみましょう。

K.factor(17)
L.factor(17)

Fractional ideal (17)
(Fractional ideal (17, c^2 - 5*c - 3)) * (Fractional ideal (17, c^2 - 7*c + 1)) * (Fractional ideal (17, c^2 - 4*c - 6)) * (Fractional ideal (17, c^2 - 4*c + 1))

$(17)$ は $K_{(3)}$ で4つの素イデアルの積に分解しています。

実際、

L.absolute_vector_space()

とすると

(Vector space of dimension 8 over Rational Field, Isomorphism map:
  From: Vector space of dimension 8 over Rational Field
  To:   Number Field in c with defining polynomial x^8 - 3*x^7 + 4*x^6 - 3*x^5 + 3*x^4 - 3*x^3 + 4*x^2 - 3*x + 1, Isomorphism map:
  From: Number Field in c with defining polynomial x^8 - 3*x^7 + 4*x^6 - 3*x^5 + 3*x^4 - 3*x^3 + 4*x^2 - 3*x + 1
  To:   Vector space of dimension 8 over Rational Field)

という結果が帰ってきますが、 $K_{(3)}$ は $\mathbb{Q}$ 上8次拡大です。 $[K : \mathbb{Q}] = 2$ なので

$[K_{(3)} : K] = 4$

となり、たしかに $(17)$ の素イデアル分解の個数と拡大次数が一致しています。すなわち、 $(17)$ が $K_{(3)}$ で完全分解することが確認できました。

面白いですね！

③ ℚ(√-163) の場合

類数1の最後の例として、 $K = \mathbb{Q}(\sqrt{-163})$ の場合を考えましょう。対応する虚数乗法をもつ楕円曲線は

$E\colon y^2 + y = x^3 - 2174420x + 1234136692$

でした。

これも例によって、ウェーバー関数が適用できる形に変形したいと思います。この変形は見かけより簡単です。

まず、 $a = 2174420, \; b = 1234136692$ とおいて

$y^2 + y = x^3 - ax + b$

としておきます。左辺の $y$ の項を消したいので、平方完成を念頭に入れつつ $y = Y - 1/2, \;\; x = X$ と変数変換すると

$(Y - 1/2)^2 + (Y - 1/2) = X^3 - aX + b$

より

$Y^2 = X^3 - ax + b + 1/4$

が得られます。

よって

$E'\colon Y^2 = X^3 - 2174420x + 1234136692 + 1/4$

ということですね。

念のため、j不変量を計算しましょう。

E1 = EllipticCurve([0, 0, 1, - 2174420, 1234136692]); E1
E1.j_invariant()
E2 = EllipticCurve([0, 0, 0, - 2174420, 1234136692 + 1/4]); E2
E2.j_invariant()

Elliptic Curve defined by y^2 + y = x^3 - 2174420*x + 1234136692 over Rational Field
-262537412640768000
Elliptic Curve defined by y^2 = x^3 - 2174420*x + 4936546769/4 over Rational Field
-262537412640768000

たしかに一致していますね。問題なさそうです！

それでは、まずは2等分点 $E'[2]$ を計算しましょう。

E = EllipticCurve([0, 0, 0, - 2174420, 1234136692 + 1/4]); E

f = E.division_polynomial(2); f
f.factor()
solve(f(x), x)

Elliptic Curve defined by y^2 = x^3 - 2174420*x + 4936546769/4 over Rational Field
4*x^3 - 8697680*x + 4936546769
(4) * (x^3 - 2174420*x + 4936546769/4)
[x == -1/4*(163/9)^(1/3)*(sqrt(163)*sqrt(3) - 272570067)^(1/3)*(I*sqrt(3) + 1) - 40020*(163/9)^(2/3)*(-I*sqrt(3) + 1)/(sqrt(163)*sqrt(3) - 272570067)^(1/3), x == -1/4*(163/9)^(1/3)*(sqrt(163)*sqrt(3) - 272570067)^(1/3)*(-I*sqrt(3) + 1) - 40020*(163/9)^(2/3)*(I*sqrt(3) + 1)/(sqrt(163)*sqrt(3) - 272570067)^(1/3), x == 1/2*(163/9)^(1/3)*(sqrt(163)*sqrt(3) - 272570067)^(1/3) + 80040*(163/9)^(2/3)/(sqrt(163)*sqrt(3) - 272570067)^(1/3)]

LaTeXに変換すると

$\begin{align} x &= -\frac{1}{4} \, \left(\frac{163}{9}\right)^{\frac{1}{3}} {\left(\sqrt{163} \sqrt{3} - 272570067\right)}^{\frac{1}{3}} {\left(i \, \sqrt{3} + 1\right)} - \frac{40020 \, \left(\frac{163}{9}\right)^{\frac{2}{3}} {\left(-i \, \sqrt{3} + 1\right)}}{{\left(\sqrt{163} \sqrt{3} - 272570067\right)}^{\frac{1}{3}}}, \\ x &= -\frac{1}{4} \, \left(\frac{163}{9}\right)^{\frac{1}{3}} {\left(\sqrt{163} \sqrt{3} - 272570067\right)}^{\frac{1}{3}} {\left(-i \, \sqrt{3} + 1\right)} - \frac{40020 \, \left(\frac{163}{9}\right)^{\frac{2}{3}} {\left(i \, \sqrt{3} + 1\right)}}{{\left(\sqrt{163} \sqrt{3} - 272570067\right)}^{\frac{1}{3}}}, \\ x &= \frac{1}{2} \, \left(\frac{163}{9}\right)^{\frac{1}{3}} {\left(\sqrt{163} \sqrt{3} - 272570067\right)}^{\frac{1}{3}} + \frac{80040 \, \left(\frac{163}{9}\right)^{\frac{2}{3}}}{{\left(\sqrt{163} \sqrt{3} - 272570067\right)}^{\frac{1}{3}}} \end{align}$

となりますが、もしかするといきなり当たりを引いたかもしれません。

この $x$ 座標をすべて $K =\mathbb{Q}(\sqrt{-163})$ に添加すると、導手 $(2)$ のray類体が得られます。

f = E.division_polynomial(2); f

K.<a> = NumberField(x^2 + 163); K
M.<b> = K.extension(f); M
L.<c> = M.galois_closure(); L

print ""

L.absolute_vector_space()

4*x^3 - 8697680*x + 4936546769
Number Field in a with defining polynomial x^2 + 163
Number Field in b with defining polynomial 4*x^3 - 8697680*x + 4936546769 over its base field
Number Field in c with defining polynomial x^6 - 3*x^5 + 12*x^4 - 19*x^3 + 94*x^2 - 85*x + 227

(Vector space of dimension 6 over Rational Field, Isomorphism map:
  From: Vector space of dimension 6 over Rational Field
  To:   Number Field in c with defining polynomial x^6 - 3*x^5 + 12*x^4 - 19*x^3 + 94*x^2 - 85*x + 227, Isomorphism map:
  From: Number Field in c with defining polynomial x^6 - 3*x^5 + 12*x^4 - 19*x^3 + 94*x^2 - 85*x + 227
  To:   Vector space of dimension 6 over Rational Field)

$K_{(2)}$ は $\mathbb{Q}$ 上の $6$ 次拡大となっていますので

$[K_{(2)} : K] = 3$

ですね。

では、ray類体における素イデアルの分解法則を考えてみましょう。

$\mathbb{Q}(\sqrt{-7})$ のときと全く同じロジックで

$\pi \equiv \pm 1 \pmod{2\mathbb{Z}[\frac{1 + \sqrt{163}}{2}]}$

であるような素元 $\pi$ によって生成される素イデアル $\pi$ は、 $K_{(2)}$ で完全分解します。

ここで、 $K = \mathbb{Q}(\sqrt{-163})$ において惰性する素数が欲しいわけですが・・・。実は、これについては過去に調べています。ドカベン素数です。
tsujimotter.hatenablog.com

まさか、この記事をもう一度引用することがあるとは思いませんでした。

やはり $\pi = 17$ を考えると、これはサインプレイのサインはV?素数になりますので、 $\mathbb{Q}(\sqrt{-163})$ で惰性します。よって条件に合致しますね。

K.factor(17)
fac = L.factor(17); fac
len(fac)

とすると、結果は

Fractional ideal (17)
(Fractional ideal (17, c^2 - 2*c - 4)) * (Fractional ideal (17, c^2 - 5)) * (Fractional ideal (17, c^2 - c + 2))
3

となり、3個の素イデアルに分解することがわかります。よって、 $(17)$ は $K_{(2)}$ で完全分解することが確認できました！

最後に、 $\pi = 37$ として、素イデアル分解を計算しましょう。 $37$ はなるか!里中パーフェクト素数なので、 $\mathbb{Q}(\sqrt{-163})$ で惰性しますね。

K.factor(37)
fac = L.factor(37); fac
len(fac)

とすると、結果は

Fractional ideal (37)
(Fractional ideal (37, c^2 + 17*c + 3)) * (Fractional ideal (37, c^2 - 19*c - 16)) * (Fractional ideal (37, c^2 - c + 13))
3

となり、3個の素イデアルに分解することがわかります。よって、 $(37)$ は $K_{(2)}$ で完全分解することが確認できました！

ルジャンドル記号 $\left(\frac{-163}{p}\right)$ は

kronecker(p, -163)

で計算できますので、 $K = \mathbb{Q}(\sqrt{-163})$ で惰性する素数はSagamathでも計算できますね。

実際、300以下の素数について、計算するとこうなります。

P = Primes()
p = P.first()
while p < 300:
    if kronecker(p, -163) == -1:
        pk = K.factor(p)
        pl = L.factor(p)
        print p, len(pk), len(pl)
    p = P.next(p)

$p = 2$ の場合は $K_{(2)}$ で分岐する素イデアルなので例外として、それ以外の $K$ で惰性する素イデアルはちゃんと完全分解することが確認できますね。